home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD012a.dsk / PANDORA.bas < prev    next >
BASIC Source File  |  2003-06-12  |  2KB  |  55 lines
  1. 100  TEXT : HOME : CLEAR 
  2. 110  REM   PROGRAM LENGTH=1200
  3. 120  REM <CTRL-M><CTRL-M>==================<CTRL-M>PAUL RAYMER<CTRL-M>BOX 42831<CTRL-M>LAS VEGAS NV 89116<CTRL-M>==================<CTRL-J>
  4. 130  REM 
  5. 140  REM  PAUL RAYMER'S
  6. 150  REM  MYTHOLOGY
  7. 160  REM  TABLEAUX
  8. 170  REM 
  9. 180  REM  PANDORA'S BOX
  10. 190  REM  (C)1982 PEC<CTRL-J>
  11. 200  DIM T$(12)
  12. 210  FOR X = 1 TO 12: READ T$(X): NEXT X
  13. 220  REM 
  14. 230  REM  BUILD BOX
  15. 240  REM 
  16. 250  INVERSE : FOR X = 13 TO 23: FOR Y = 26 TO 40: VTAB X: HTAB Y: PRINT " ";: NEXT Y: NEXT X: NORMAL 
  17. 260  FOR X = 13 TO 23: VTAB X: HTAB 25: PRINT "#";: NEXT X
  18. 270  VTAB 15: HTAB 29: INVERSE : PRINT "PANDORA'S"
  19. 280  VTAB 16: HTAB 32: PRINT "BOX": NORMAL 
  20. 290  FOR Z = 1 TO 1000: NEXT Z
  21. 300  REM 
  22. 310  REM  OPEN BOX
  23. 320  REM 
  24. 330  FOR X = 1 TO 3
  25. 340  VTAB 13 -X: HTAB 25: PRINT "#": VTAB 24 -X: HTAB 25: PRINT " ";: FOR Z = 1 TO 1000: NEXT Z: NEXT X
  26. 350  REM 
  27. 360  REM  TROUBLES START
  28. 370  REM 
  29. 380  FOR TR = 1 TO 12
  30. 390  IF TR = 11  OR TR = 12  THEN R = TR: GOTO 420
  31. 400 R =  INT(10 * RND(1)) +1
  32. 410  IF T$(R) = "!"  THEN 400
  33. 420 T$ = T$(R)
  34. 430 L = 24
  35. 440  FOR X = 1 TO  LEN(T$)
  36. 450  VTAB 23: HTAB L: PRINT  MID$ (T$,1,X);: IF  MID$ (T$,X,1) = "?"  THEN  PRINT  CHR$(7);
  37. 460 L = L -1
  38. 470  FOR Z = 1 TO 200: NEXT Z
  39. 480  NEXT X
  40. 490 T$(R) = "!"
  41. 500  NEXT TR
  42. 510  REM 
  43. 520  REM   CLOSE BOX
  44. 530  REM  
  45. 540  FOR X = 3 TO 1  STEP  -1
  46. 550  VTAB 13 -X: HTAB 25: PRINT " ": VTAB 24 -X: HTAB 25: PRINT "#";: FOR Z = 1 TO 1000: NEXT Z: NEXT X
  47. 560  REM 
  48. 570  REM  HOPE REMAINS!
  49. 580  REM 
  50. 590  INVERSE : VTAB 22: HTAB 31: PRINT "HOPE": NORMAL 
  51. 600  FOR Z = 1 TO 3000: NEXT Z: VTAB 23: HTAB 1: PRINT  CHR$(13); CHR$(4);"RUN MYTHMENU"
  52. 610  REM 
  53. 620  REM  GRIEF AND WOE
  54. 630  REM 
  55. 640  DATA     <TROUBLE.......,<GRIEF.........,<AGGRAVATION...,<UNHAPPINESS...,<GLITCHES......,<ACHES & PAINS.,<RED TAPE......,<MISERY........,<BUGS..........,?SYNTAX ERROR..,...............,WHAT IS LEFT?->